ВойтиРегистрация

Мелодичный Ардуино

← Алгоритмы
Мелодичный Ардуино

В этом примере используется динамик piezo, для проигрывания мелодий. Посылается волна с формой квадрата соответствующей частоты на динамик, который воспроизводит соответствующий звук.
Вычисление тонов звука рассчитывается по следующей математической формуле:

timeHigh = period / 2 = 1 / (2 * toneFrequency),

где разные тона описаны в нижеприведённой таблице:

note    frequency    period    timeHigh
c           261 Hz       3830       1915 	
d           294 Hz       3400       1700 	
e           329 Hz       3038       1519 	
f           349 Hz       2864       1432 	
g           392 Hz       2550       1275 	
a           440 Hz       2272       1136 	
b           493 Hz       2028       1014	
C           523 Hz       1912        956


У Piezos есть полярность. Коммерческие устройства обычно имеют красный (+) и черный (-). Соединяем красный провод с цифровым пином 9, а чёрный провод заземляем. Иногда возможно, что при приобретении Piezo, его элементы будут без пластмассового корпуса, тогда они будут выглядеть как металлический диск.

piezo подключён к 9-му пину


КОД:

int speakerPin = 9;

int length = 15; // the number of notes
char notes[] = "ccggaagffeeddc "; // a space represents a rest
int beats[] = { 1, 1, 1, 1, 1, 1, 2, 1, 1, 1, 1, 1, 1, 2, 4 };
int tempo = 300;

void playTone(int tone, int duration) {
  for (long i = 0; i < duration * 1000L; i += tone * 2) {
    digitalWrite(speakerPin, HIGH);
    delayMicroseconds(tone);
    digitalWrite(speakerPin, LOW);
    delayMicroseconds(tone);
  }
}

void playNote(char note, int duration) {
  char names[] = { 'c', 'd', 'e', 'f', 'g', 'a', 'b', 'C' };
  int tones[] = { 1915, 1700, 1519, 1432, 1275, 1136, 1014, 956 };

  // play the tone corresponding to the note name
  for (int i = 0; i < 8; i++) {
    if (names[i] == note) {
      playTone(tones[i], duration);
    }
  }
}

void setup() {
  pinMode(speakerPin, OUTPUT);
}

void loop() {
  for (int i = 0; i < length; i++) {
    if (notes[i] == ' ') {
      delay(beats[i] * tempo); // rest
    } else {
      playNote(notes[i], beats[i] * tempo);
    }

    // pause between notes
    delay(tempo / 2); 
  }
}


Английский оригинал
technik 11.12.2009 в 15.57 (обновлен 11.12.2009 в 16.01) комментарии 0 0

комментарии(0)

Комментировать

Для добавления комментария авторизируйтесь.

Разделы

Последние комментарии:
Последние статьи:
© 2012 pobot.ru